Статья: Web Services и MS Visual FoxPro Часть 4

• Web Service для нашего большого примера.
• Публикация Web Service (некоторые ключевые моменты).

*/--------------------------------------------------------------------------/*
*
* MS VFP version..: 9.0 (так как применим новые данные совместимые с SQL Server)
* Program-ID......: WS_MES_SERVER.PRG
* Purpose.........: Непосредственно WEB Service
* Project Manager.:
* Programmer......: Sergey Chavlytko
* Start...........: 23/05/2005
* Last edited.....: 23/05/2005
*
* (С) www.sergey.co.uk 2005
*/--------------------------------------------------------------------------/*

DEFINE CLASS WS_MES_SERVER AS SESSION OLEPUBLIC

  PROCEDURE INIT && процедура, выполняемая при каждом вызове Web Service
* Вы можете писать сюда все что Вам необходимо для инициализации работы программы
* Например, глобальные переменные

  SET DELETED ON
  SET DATE DMY
  SET EXCLUSIVE OFF
  SET MULTILOCKS ON
  SET REPROCESS TO 1000
  SET STRICTDATE TO 0
  SET CENTURY ON

* явно определяем установки среды, которые будут видны во всем Web Service
* обычно эту информацию следует записывать во внешний DBF файл конфигурации
  PUBLIC gcWebSDat
  gcWebSDat='C:\ws_message\server\'

*!* If you do any work with SQL Pass-Through
*!* these settings are a good idea.
  SQLSETPROP(0,"DispLogin",3)
  SQLSETPROP(0,"DispWarnings",.F.)
  ENDPROC

*
* Процедура login в систему - принимает в качестве параметров login и password
* выдает курсор с одной строкой в виде информации о клиенте
*
  PROCEDURE login(m.lclog,m.lcpsw) AS STRING
  IF !DBUSED('DBWS')
    OPEN DATABASE (gcWebSDat+'DBWS')
  ENDIF
  lcXMLa11=-1
  lcXMLa11=sp_user_login_xml(m.lclog,m.lcpsw)
  CLOSE DATABASES ALL
  RETURN (lcXMLa11)
  ENDPROC

*
* В каждой процедуре передается снова логин, пароль
* и дополнительные параметры. В реальной жизни я их шифрую,
* причем все без исключения.
*
* В принципе, систему безопасности можно и ослабить...
*
* Данный пример показывает, как можно упростить разработку
* Web Service при выполнении однотипных операций
* кроме того такая некоторая "запутанность" приводит к повышению
* уровня безопасности.
*
  PROCEDURE message_read(m.lckey_word,m.lcUser_nick, m.lcpassword,m.lcparameter1,m.lcparameter2,;
    m.lcparameter3,m.lcparameter4,m.lcparameter5,m.lcparameter6) AS STRING
  IF !DBUSED('DBWS')
    OPEN DATABASE (gcWebSDat+'DBWS')
  ENDIF
  lcXMLa11=-1
  DO CASE
  CASE m.lckey_word='READ_MESSAGES_START' && чтение заголовков сообщений
    lcXMLa11=sp_message_read(m.lcparameter1, m.lcUser_nick, m.lcpassword, m.lcparameter2)
  CASE m.lckey_word='READ_ALL_USERS' && чтение всех пользователей
    lcXMLa11=sp_users_read_xml(m.lcUser_nick, m.lcpassword)
  CASE m.lckey_word='ADD_NEW_MESSAGE' && добавление нового сообщения
    lcXMLa11=sp_new_message_add(m.lcUser_nick, m.lcpassword,m.lcparameter1,m.lcparameter2,m.lcparameter3)
  CASE m.lckey_word='READ_THREAD_START' && чтение всех ответов на конретное сообшение
    lcXMLa11=sp_thread_read(m.lcUser_nick, m.lcpassword,m.lcparameter1)
  CASE m.lckey_word='ADD_EXISTS_MESSAGE' && добавление ответа на существующее сообщение
    lcXMLa11=sp_existed_message_add(m.lcUser_nick, m.lcpassword,m.lcparameter1,m.lcparameter2)
  CASE m.lckey_word='DELETE_THREAD' && Удаление всего потока сообщения с сервера
    lcXMLa11=sp_message_delete(m.lcUser_nick, m.lcpassword,m.lcparameter1)
  CASE m.lckey_word='DELETE_ANSWER' && Удаление одного ответа из сообщения с сервера
    lcXMLa11=sp_answer_delete(m.lcUser_nick, m.lcpassword,m.lcparameter1,m.lcparameter2)
  CASE m.lckey_word='READ_PROFILE_USERS' && Чтение профиля пользователя с сервера
    lcXMLa11=sp_users_profile_read_xml(m.lcUser_nick, m.lcpassword,m.lcparameter1)
  CASE m.lckey_word='ADD_NEW_USER' && Добавление/изменение профиля клиента
    lcXMLa11=sp_users_add_edit(m.lcUser_nick, m.lcpassword,m.lcparameter1,m.lcparameter2)

  ENDCASE
  CLOSE DATABASES ALL
  RETURN (lcXMLa11)
  ENDPROC

* это и есть наш тестовый пример
  PROCEDURE test() AS INTEGER
  RETURN (1)
  ENDPROC

ENDDEFINE

Как Вы видите, ничего серьезного и таинственного. В процедуре INIT можно задавать любые установки, которые будут потом видимы всем методам внутри класса. Благодаря применению ХП в базе данных, здесь все свелось просто к вызову соответствующих ХП с параметрами. Причем параметр может быть XML файл, в котором можно спрятать довольно большую таблицу или много других параметров (тем самым обходя ограничения на количество переданных праметров). В практической жизни таблицы я вначале сохраняю в виде текстового файла с разделителями, затем этот файл вставляю в поле MEMO BINARY курсора, преобразую получившуюся таблицу с одной строкой в XML курсор и отправляю его по сети. Так на файлах размером более 5 Mb получается существенная экономия интернет-трафика и, соответственно, повышение скорости работы.

Вы уменьшаете уровень защищенности Вашего компьютера, так что смотрите сами, чтобы кто-то с негативными намерениями не испортил Вашу информацию.